Dilatace času

Následující aplet zobrazuje graficky nárůst času, který měří pozorovatel vůči pohybujícím se hodinám, ve srovnání s vlastním časem v závislosti na podílu (v/c), kde v je velikost rychlosti relativního pohybu pozorovatele vůči hodinám a c je velikost rychlosti světla ve vakuu.

Tlačítkem Ulož obrázek se uloží právě zobrazené "bílé" okno do aktuální složky (složka, v níž je uložen tento notebook) pod jménem, které je uloženo v proměnné jmenosouboru. K tomuto jménu souboru je při opakovaném ukládání grafu přidáváno pořadové číslo.
Pozor! Při každém spuštění tohoto apletu se začínají soubory číslovat opět od jedné! Tak může dojít k přepsání minule uložených obrázků.

© Jaroslav Reichl, 2008

Příprava pro vykreslení grafu

jmenosouboru="str_dilatace_.jpg";
cesta=NotebookDirectory[];
pocetulozeni=0;

x1=0;x2=1;
y1=-1;y2=5;

deltabeta=0.0001;
t0=1;

tloustka=0.005;
velikostbodu=0.02;

barva=Black;
barvagrafu=Blue;
barvabodu=Red;
barvat0=Darker[Red,0.3];
barvav=barvat0;
barvat=barvat0;

DilataceCasu=Manipulate[Deploy[
t[nasobekc_]:=(t0/(Sqrt[1-(nasobekc^2)]));
bodgrafu=Point[{beta,t[beta]}];

grafik=Show[
Plot[t[nasobekc],{nasobekc,0,1-deltabeta},PlotStyle->{Thickness[tloustka],barvagrafu},AxesLabel->{"(v/c)","\!\(\*FractionBox[\(t\), \(t´\)]\)"},PlotRange->All,AxesOrigin->{0,0},Ticks->{Automatic,{0,1,2,3,4,5}},AxesStyle->Directive[barva,Thickness[0.7tloustka]]],
Graphics[{
{barvabodu,PointSize[velikostbodu],bodgrafu},
If[zobrazithodnoty,
{Text[Style[StringJoin["τ = t´ = ",ToString[Round[t0,0.01]]," s"],20,barvat0,FontFamily->Times],{0.05x2,y1},{Left,Bottom}],
Text[Style[StringJoin["v = ",ToString[beta]," c"],20,barvav,FontFamily->Times],{0.5x2,y1},{Center,Bottom}],
Text[Style[StringJoin["t = ",ToString[Round[t[beta],deltabeta]]," s"],20,barvat,FontFamily->Times],{0.95x2,y1},{Right,Bottom}]},
Text[""]]
}],
FormatType->StandardForm,PlotRange->{{x1,x2},{y1,y2}},ImageSize->520
]],

{{beta,0,Style["(v/c)",20,barvav,Italic]},0,1-deltabeta,deltabeta},
Delimiter,
{{zobrazithodnoty,True,Style["zobrazit hodnoty",15,barva,FontFamily->Times]},{True,False},ControlType->Checkbox},
Delimiter,
Button[" Ulož obrázek ",{pocetulozeni=pocetulozeni+1,Export[StringInsert[StringJoin[cesta,jmenosouboru],ToString[pocetulozeni],-5],grafik]},ImageSize->{100,Automatic}],
ControlPlacement->Left,
FrameLabel->{Style["© Jaroslav Reichl, 2008",10,Black,FontFamily->Times],"",Style["Dilatace času",25,Black,FontFamily->Times],""}];

Spuštění animace
Zpracujte běžným způsobem následující buňku a na dotaz, který se objeví, odpovězte ANO.

DilataceCasu