Seznámení se systémem Mathematica 7

Grafické výstupy systému

© Jaroslav Reichl, SPŠST Panská, Praha
reichl@panska.cz

Obsah

Prezentace obsahuje tato témata:

Výstupy proměnných a grafů I.
9. úkol
Výstupy proměnných a grafů II.
10. úkol
Výstupy proměnných a grafů III.
11. úkol

Jaroslav Reichl, SPŠST Panská, Praha, © 2010

Výstupy proměnných a grafů I.

Mathematica používá několik způsobů, jak přehledně zobrazit výsledky provedeného výpočtu:

Výpis bez použití funkce nebo příkazu - nejjednodušší, ale také nejméně elegantní.

a=3;
b=7;
a+b (*Výstup součtu dvou čísel*)
a b (*Výstup součinu dvou čísel*)

Print[promenna] nebo Print[text, promenna] - tento výstup slouží pro zobrazení výsledku řešení, bez grafického výstupu (žádný graf, žádné "obrázky").

rovnice=3x-7==x+2
reseni=Solve[rovnice,x];
koren=x/.reseni[[1]]
Print["Řešením rovnice ",rovnice," je číslo ",koren,"."]

Plot[funkce[x], {x, (Subscript[x, min]), (Subscript[x, max])}] - vykreslí graf funkce na daném intervalu. S využitím nápovědy je možné nalézt další parametry této funkce. Zejména užitečné jsou:
	PlotStyle->{barva_grafu,Thickness[tloustka_grafu],styl_cary}, kde za styl_cary lze volit Dotted (tečkovaná), Dashed (čárkovaná) a nebo si navolit svůj styl pomocí dalších parametrů funkce Dashed;
	AxesOrigin->{(Subscript[x, 0]),(Subscript[y, 0])}, kde (Subscript[x, 0]) a (Subscript[y, 0]) jsou souřadnice průsečíku os kartézského systému, do něhož je graf vykreslován. Mathematica se snaží zobrazit graf optimálně, což ovšem někdy může být nepřehledné.
	AspectRatio->Automatic nastavení poměru výšky a šířky v grafu. Pokud není uvedno jinak, je přednastaven poměr zlatého řezu. Grafy jsou sice pěkné, ale kružnice nevypadá jako kružnice, ale jako elipsa, ... Nicméně pro grafy řady funkcí je užitečné ponechat původní nastavení - graf se "lépe vejde na obrazovku".
	AxesLabel->{"popis_osy_x","popis_osy_y"} - do popisu jednotlivých os lze vkládat i zlomky, abychom mohli korektně popsat i osy grafů fyzikálních závislostí.
	PlotRange->{{(Subscript[x, min]),(Subscript[x, max])},{(Subscript[y, min]),(Subscript[y, max])}} - rozsah, v jakém se má graf funkce zobrazit. Ve většině případů není nutné tuto funkci používat, ale u některých typů zadaných funkcí to nutné je - Mathematica je vykreslí optimálně a přitom z grafu nepoznáme důležité vlastnosti funkce (extrémy, ...).

funkce[x_]:=((Sin[x])^3)+1
Plot[funkce[x],{x,-2π,3π},PlotStyle->{Blue,Thickness[0.007]},AxesOrigin->{0,0},AspectRatio->Automatic,AxesLabel->{"x","y"}]

Graphics[graficke_vystupy,parametry] - zobrazí objekty v grafickém módu - např.:
	Point[{x,y}] - bod o souřadnicích [x; y];
	Line[{{(Subscript[x, 1]),(Subscript[y, 1])},{(Subscript[x, 2]),(Subscript[y, 2])}, ...}] - (lomená) čára procházející body o souřadnicích [(Subscript[x, 1]); (Subscript[y, 1])], [(Subscript[x, 2]); (Subscript[y, 2])], ...;
	Arrow[{{(Subscript[x, 1]),(Subscript[y, 1])},{(Subscript[x, 2]),(Subscript[y, 2])}}] - vektor, který má počáteční bod o souřadnicích [(Subscript[x, 1]); (Subscript[y, 1])] a koncový bod o souřadnicích [(Subscript[x, 2]); (Subscript[y, 2])];
	Circle[{(Subscript[x, stred]),(Subscript[y, stred])},polomer] - kružnice se středem v bodě [(Subscript[x, stred]); (Subscript[y, stred])] a poloměrem polomer;
	Disk[{(Subscript[x, stred]),(Subscript[y, stred])},polomer] - kruh se středem v bodě [(Subscript[x, stred]); (Subscript[y, stred])] a poloměrem polomer;
	Rectangle[{(Subscript[x, min]),(Subscript[y, min])},{(Subscript[x, max]),(Subscript[y, max])}] - plný obdélník, jehož levý dolní vrchol má souřadnice [(Subscript[x, min]); (Subscript[y, min])] a pravý horní vrchol má souřadnice [(Subscript[x, max]); (Subscript[y, max])];
	Text[text] nebo Text[Style[text,velikost,barva],{x,y},{vod_zarov,svisl_zarov}] - v grafickém režimu vypíše text fontem o velikosti velikost barvou barva. Vypsaný text bude zarovnán vodorovně (vod_zarov) a svisle (svisl_zarov) na bod o souřadnicích [x; y];
	...

x1=0;
y1=0;
polomer=5;
kruznice=Circle[{x1,y1},polomer];
bod=Point[{x1,y1}];
ctverec=Rectangle[{x1-polomer,y1-polomer},{x1+polomer,y1+polomer}];
uhlopricka=Line[{{x1-polomer,y1-polomer},{x1+polomer,y1+polomer}}];
vektor={
Arrowheads[{0,0.1}],
Arrow[{{x1+polomer,y1-polomer},{x1-polomer,y1+polomer}}]};
grafika=Graphics[{
{Darker[Green],PointSize[0.025],bod},
{Red,Thickness[0.007],kruznice},
{Blue,Opacity[0.25],Dashed,Thickness[0.009],ctverec},
{Black,Dotted,Thickness[0.005],uhlopricka},
{Orange,Thickness[0.006],vektor},
Text[Style["Text vypsaný v grafickém režimu.",15,Orange,FontFamily->Times,Underlined],{x1-polomer,y1},{Left,Bottom}]
}]
Show[grafika,ImageSize->500]

Show[vystupy,parametry] - zobrazí do jednoho grafu několik grafických výstupů přes sebe. Tímto způsobem je možné např. zobrazit do jednoho grafu jednotlivé body spolu s křivkou, která jimi prochází, graf fyzikální závislosti společně se schématem zapojení nebo obrázkem ilustrujícím postup řešení, ...

graf1=Plot[x+1,{x,-10,10},PlotStyle->{Red,Thickness[0.007]}];
graf2=Plot[x Sin[x],{x,-10,10},PlotStyle->{Blue,Dashed,Thickness[0.005]}];
Show[graf1, graf2,
AxesOrigin->{0,0},AspectRatio->Automatic,AxesLabel->{"x","y"}]

Grid[{{vyraz1,vyraz2,...},{vyraz3,vyraz4,...},...}] - zobrazí zadané vyrazy do dvojrozměrné mřížky.

Grid[{{"První","Druhý"},{"Třetí","Čtvrtý"}}]
Grid[{{"První"},{"Druhý","Třetí","Čtvrtý"}}]

Jaroslav Reichl, SPŠST Panská, Praha, © 2010

9. úkol: Výstupy proměnných a grafů I.

Uložte do proměnných a a b náhodné číslo z intervalu (0; 1) a s proveďte operace a + b,
a - b, a . b a a : b. Výsledky těchto operací pěkně vypište.

Řešení

a=Random[];
b=Random[];

Print["Součet čísel ",a," a ",b," je roven ",a+b,"."]
Print["Rozdíl čísel ",a," a ",b," je roven ",a-b,"."]
Print["Součin čísel ",a," a ",b," je roven ",a b,"."]
Print["Podíl čísel ",a," a ",b," je roven ",(a/b),"."]

Vykreslete graf funkce y = (x^2)+2x-35. Funkci vykrelete červenou tečkovanou čarou tloušťky 0,008 tak, že osy kartézského systému souřadnic se budou protínat v místě vrcholu paraboly, která je grafem zadané funkce. Osy systému souřadnic budou popsány popisky "osa x" a "osa y".

Řešení

ClearAll["Global`*"];
funkce[x_]:=(x^2)+2x-35
reseni=Solve[funkce[x]==0,x];
koren1=x/.reseni[[1]];
koren2=x/.reseni[[2]];
vrcholx=((koren1+koren2)/2);
vrcholy=funkce[vrcholx];
Plot[funkce[x],{x,-10,10},PlotStyle->{Red,Dotted,Thickness[0.009]},AxesOrigin->{vrcholx,vrcholy},AxesLabel->{"osa x","osa y"}]

Zobrazte do kartézského systému souřadnic modrou tečkovanou čarou tloušťky 0,01 graf funkce y = sin(x/2)+2 na intervalu <-π; π>. Do téhož kartézského systému zobrazte kružnici se středem v počátku soustavy souřadnic (tj. v bodě [0; 0]) a poloměrem 2. Popište osy soustavy souřadnice a dbejte na to, aby zobrazená kružnice vypadala skutečně jako kružnice.

Řešení

ClearAll["Global`*"];
funkce[x_]:=2Sin[(x/2)]+1
graf=Plot[funkce[x],{x,-π,π},PlotStyle->{Blue,Dashed,Thickness[0.01]}];
kruznice=Circle[{0,0},2];
Show[
graf,
Graphics[
{Red,Thickness[0.007],kruznice}],
AxesOrigin->{0,0},AxesLabel->{"x","y"},PlotRange->All,AspectRatio->Automatic]

Zobrazte do kartézského systému souřadnic pravidelný šestiúhelník vepsaný do kružnice se středem v počátku systému souřadnic a poloměrem 5 jednotek. Spolu se šestiúhelníkem, který bude zobrazen červenou čárou tloušťky 0,008, zobrazte fialovou barvou i jeho vrcholy (body budou mít velikost 0,025) a černou tečkovanou čárou tloušťky 0,005 zobrazte i kružnici, do které je vepsán.

Řešení

ClearAll["Global`*"];
x0=0;y0=0;
polomer=5;
pocetvrcholu=6;
kruznice=Circle[{x0,y0},polomer];
vrcholy=Table[Point[{x0+polomer Cos[((2π)/pocetvrcholu)i],y0+polomer Sin[((2π)/pocetvrcholu)i]}],{i,0,pocetvrcholu-1,1}];
spojnice=Table[Line[{{x0+polomer Cos[((2π)/pocetvrcholu)i],y0+polomer Sin[((2π)/pocetvrcholu)i]},{x0+polomer Cos[((2π)/pocetvrcholu)(i+1)],y0+polomer Sin[((2π)/pocetvrcholu)(i+1)]}}],{i,0,pocetvrcholu-1,1}];
Show[
Plot[0,{x,0,0.1}],(*Způsob, jak k obrázku dostat kartézský systém souřadnic. Druhá varianta: vykreslit osy manuálně - např. pomocí funkce Line[]*)
Graphics[{
{Black,Dotted,Thickness[0.005],kruznice},
{Red,Thickness[0.008],spojnice},
{Magenta,PointSize[0.025],vrcholy}
}],
AxesOrigin->{0,0},AxesLabel->{"x","y"},PlotRange->All,AspectRatio->Automatic]

Zobrazte do kartézského systému souřadnic domeček, který lze nakreslit jedním jedním tahem (je složen ze čtverce s oběma úhlopříčkami a trojúhelníku). Domeček bude umístěn na ose x symetricky vzhledem k ose y. Jeho délka bude 10 jednotek a výška střechy je 5 jednotek. Domeček zobrazte fialovou čarou tloušťky 0,01.

Řešení

ClearAll["Global`*"];
x0=0;y0=0;
delka=10;
vyskastrechy=5;
domecek=Line[{{x0-(delka/2),y0},{x0+(delka/2),y0},{x0+(delka/2),y0+delka},{x0-(delka/2),y0+delka},{x0-(delka/2),y0},{x0+(delka/2),y0+delka},{x0,y0+delka+vyskastrechy},{x0-(delka/2),y0+delka},{x0+(delka/2),y0}}];
Show[
Plot[0,{x,0,0.1}],(*Způsob, jak k obrázku dostat kartézský systém souřadnic. Druhá varianta: vykreslit osy manuálně - např. pomocí funkce Line[]*)
Graphics[
{Magenta,Thickness[0.01],domecek}],
AxesOrigin->{0,0},AxesLabel->{"x","y"},PlotRange->All,AspectRatio->Automatic]

Zobrazte logo software Mathematica, které lze stáhnout z internetu na adrese http://www.mathematica-forum.cz/. Spolu s ním zobrazte graf funkce y=sin x na intervalu <-π; 5π> modrou tečkovanou silnější čarou. Popsané objekty zobrazte: a) pod sebe, b) vedle sebe.

Řešení

obrazek=Import["http://www.mathematica-forum.cz/m_logo.jpg"];
graf=Plot[Sin[x],{x,-π,5π},PlotStyle->{Blue,Dotted,Thickness[0.01]},AxesOrigin->{0,0}];
Grid[{{obrazek},{graf}}]
Grid[{{obrazek,graf}}]

Jaroslav Reichl, SPŠST Panská, Praha, © 2010

Výstupy proměnných a grafů II.

Další grafické výstupy systému Mathematica jsou analogické k těm, které již byly popsány, ale využívají pro jinak zadané funkce.

ParametricPlot[{x[t],y[t]}, {t, (Subscript[t, min]), (Subscript[t, max])}] - vykreslí graf funkce, která je zadána parametricky, tj. jako závislost x-ové a y-ové souřadnice na parametru t: x(t) a y(t). Parametr t přitom vybíráme z intervalu <(Subscript[t, min]); (Subscript[t, max])>. Parametry této funkce jsou stejné, jako parametry funkce Plot[].

a=3;
b=4;
funkcex[t_]:=a Cos[t];
funkcey[t_]:=b Sin[t];
ParametricPlot[{funkcex[t],funkcey[t]},{t,0,2π},AspectRatio->Automatic]

PolarPlot[r[φ], {φ, (Subscript[φ, min]), (Subscript[φ, max])}] - vykreslí do poloráních souřadnic graf funkce r[φ] pro úhly φ v daném intervalu. Parametry této funkce jsou stejné, jako parametry funkce Plot[].

funkce[t_]:=Sin[5t]
graf1=PolarPlot[funkce[t],{t,0,2π},PlotStyle->{Red,Thickness[0.005]}];
graf2=Plot[funkce[t],{t,0,2π},PlotStyle->{Blue,Dotted,Thickness[0.005]}];
Show[
graf1,graf2,
AxesOrigin->{0,0},AspectRatio->Automatic,ImageSize->700]

RegionPlot[vyraz[x,y], {x, (Subscript[x, min]), (Subscript[x, max])},{y, (Subscript[y, min]), (Subscript[y, max])}] - vykreslí oblast, pro kterou je splněna podmínka vyraz[x,y]. Parametry této funkce jsou stejné, jako parametry funkce Plot[].

RegionPlot[y≤2x+3,{x,-10,10},{y,-10,10},PlotStyle->{Orange}]
RegionPlot[y≤2x+3,{x,-10,10},{y,-10,10},BoundaryStyle->{Red,Thickness[0.007]},PlotStyle->None,Frame->False,Axes->True]

ContourPlot[vyraz[x,y],{x, (Subscript[x, min]), (Subscript[x, max])},{y, (Subscript[y, min]), (Subscript[y, max])}] - vykreslí obrysy (kontury) výrazu vyraz[x,y] jako funkci proměnných x a y.
ContourPlot[vyraz1[x,y]==vyraz1[x,y],{x, (Subscript[x, min]), (Subscript[x, max])},{y, (Subscript[y, min]), (Subscript[y, max])}] - vykreslí křivky charaktrizované rovnicí vyraz1[x,y]=vyraz2[x,y].
Parametry této funkce jsou stejné, jako parametry funkce Plot[].

ContourPlot[Sin[x],{x,-10,10},{y,-10,10}]
ContourPlot[2Sin[x]+2Cos[y]==1,{x,-10,10},{y,-10,10}]

LogPlot[funkce[x], {x, (Subscript[x, min]), (Subscript[x, max])}] - vykreslí graf funkce funkce[x] v daném intervalu do grafu, jehož svislá osa je škálována logaritmicky. Parametry této funkce jsou stejné, jako parametry funkce Plot[].

barvae=Red;
barvalog=Blue;
barvax=Magenta;
LogPlot[
Tooltip[{(E^x),Log[x],x},LabelStyle->Directive[Black,Bold]],{x,0.1,5},PlotStyle->{{barvae,Thickness[0.007]},{barvalog,Thickness[0.007]},{barvax,Thickness[0.007]}}]

Jaroslav Reichl, SPŠST Panská, Praha, © 2010

10. úkol: Výstupy proměnných a grafů II.

Vykreslete do kartézského systému souřadnic kardoidu, která je parametricky popsána rovnicemi x=a(2cos t-cos (2t)) a y=a(2sin t-sin (2t)) pro a = 3. Křivku nakreslete červenou barvou tloušťky 0.008. Osy systému souřadnic budou popsány popisky "x" a "y".

Řešení

ClearAll["Global`*"];
a=3;
x[t_]:=a(2Cos[t]-Cos[2t])
y[t_]:=a(2Sin[t]-Sin[2t])
ParametricPlot[{x[t],y[t]},{t,0,2π},PlotStyle->{Red,Thickness[0.008]},AxesOrigin->{0,0},AspectRatio->Automatic,AxesLabel->{"x","y"}]

Vykreslete do polárního grafu kružnici o poloměru 2 jednotky. Kružnice bude vykreslená červenou barvou tloušťky 0,006. Do téhož polárního grafu vykreslete modrou barvou stejné tloušťky graf funkce y= 2+(1/10)sin10x. Osy systému souřadnic budou popsány popisky "φ" a "r".

Řešení

ClearAll["Global`*"];
funkce[x_]:=2+((Sin[10x])/10)
PolarPlot[{2,funkce[x]},{x,0,2π},PlotStyle->{{Red,Thickness[0.006]},{Blue,Thickness[0.006]}},AxesOrigin->{0,0},AxesLabel->{"φ","r"}]

Řešte soustavu nerovnic x+2y<4, 2x-3<4y a 2y≤x<0 s reálnými neznámými x a y. Zobrazte řešení dané nerovnice graficky.

Řešení

vyraz1=x+2y<4;
vyraz2=2x-3<4y;
vyraz3=2y≤x<0;
Reduce[{vyraz1,vyraz2,vyraz3},{x,y}]
tloustka=0.006;
graf11=RegionPlot[vyraz1,{x,-5,5},{y,-6,5},BoundaryStyle->{Red,Thickness[tloustka]},PlotStyle->None];
graf12=RegionPlot[vyraz2,{x,-5,5},{y,-6,5},BoundaryStyle->{Blue,Thickness[tloustka]},PlotStyle->None];
graf13=RegionPlot[vyraz3,{x,-5,5},{y,-6,5},BoundaryStyle->{Magenta,Thickness[tloustka]},PlotStyle->None];
graf2=RegionPlot[{vyraz1∧vyraz2∧vyraz3},{x,-5,5},{y,-6,5}];
Show[graf2,graf11,graf12,graf13,
AspectRatio->Automatic,Axes->True,Frame->False]

Řešte soustavu nerovnic y≥4x-1, (x^2)+(((y+2))^2)≥9 a x<0 s reálnými neznámými x a y. Zobrazte řešení dané nerovnice graficky.

Řešení

vyraz1=y≥4x-1;
vyraz2=(x^2)+(((y+2))^2)≥9;
vyraz3=x<0;
Reduce[{vyraz1,vyraz2,vyraz3},{x,y}]
tloustka=0.006;
graf11=RegionPlot[vyraz1,{x,-5,5},{y,-6,5},BoundaryStyle->{Red,Thickness[tloustka]},PlotStyle->None];
graf12=RegionPlot[vyraz2,{x,-5,5},{y,-6,5},BoundaryStyle->{Blue,Thickness[tloustka]},PlotStyle->None];
graf13=RegionPlot[vyraz2,{x,-5,5},{y,-6,5},BoundaryStyle->{Magenta,Thickness[tloustka]},PlotStyle->None];
graf2=RegionPlot[{vyraz1∧vyraz2∧vyraz3},{x,-5,5},{y,-6,5}];
Show[graf2,graf11,graf12,graf13,
AspectRatio->Automatic,Axes->True,Frame->False]

Jaroslav Reichl, SPŠST Panská, Praha, © 2010

Výstupy proměnných a grafů III.

Většina výše uvedených funkcí, které realizují grafické výstupy systému Mathematica mají svou analogii pro zobrazení trojrozměrných grafů. Většinou se syntaxe změní tak, že jméno dané grafické funkce se doplní dvěma znaky 3D a do parametrů funkce se přidá další proměnná.
Nebudeme uvádět všechny 3D grafické výstupy - jsou opravdu analogické 2D grafickým výstupům.

Plot3D[funkce[x,y], {x, (Subscript[x, min]), (Subscript[x, max])},{y, (Subscript[y, min]), (Subscript[y, max])}] - vykreslí graf funkce na daném intervalu proměnné x a proměnné y. S využitím nápovědy je možné nalézt další parametry této funkce, které jsou velmi podobné jako parametry funkce Plot[] popsané výše.

funkce[x_,y_]:=(x^2)+y Sin[2x]
Plot3D[funkce[x,y],{x,-10,10},{y,-10,10},PlotStyle->{Green,Thickness[0.008]},Boxed->False,AxesOrigin->{0,0,0}]

ParametricPlot3D[{x[t],y[t],z[t]}, {t, (Subscript[t, min]), (Subscript[t, max])}] - vykreslí graf funkce, která je zadána parametricky, tj. jako závislost x-ové, y-ové a z-ové souřadnice na parametru t: x(t), y(t) a z(t). Parametr t přitom vybíráme z intervalu <(Subscript[t, min]); (Subscript[t, max])>. Parametry této funkce jsou stejné, jako parametry funkce Plot[].

a=3;
b=4;
funkcex[t_]:=a Cos[t];
funkcey[t_]:=b Sin[t];
funkcez[t_]:=(Sqrt[(a^2)+(b^2)])Sin[a t]Sin[b t]
ParametricPlot3D[{funkcex[t],funkcey[t],funkcez[t]},{t,0,2π},AspectRatio->Automatic]

RevolutionPlot3D[funkce[x], {x, (Subscript[x, min]), (Subscript[x, max])}] - vykreslí plochu, která vznikne rotací grafu funkce funkce[x] kolem osy y na zadaném intervalu. Uvedená deklarace je pouze jeden z několika způsobů. Parametry této funkce jsou podobné, jako parametry funkce Plot[].

RevolutionPlot3D[(x^2),{x,0,3}]

a další funkce

Jaroslav Reichl, SPŠST Panská, Praha, © 2010

11. úkol: Výstupy proměnných a grafů III.

Rovnice postupného vlnění má tvar y=(Subscript[y, m])sin 2π((t/T)-(x/λ)). Nakreslete graf závislosti okamžité výchylky y na souřadnici x a na čase t pro vlnění s parametry: perioda T kmitání zdroje je 5 s, amplituda výchylky (Subscript[y, m]) je 15 cm a vlnová délka λ vlnění je 7 m. Závislost nakreslete fialovou barvou a vypočítejte velikost rychlosti šíření vlny v daném prostředí.

Řešení

ClearAll["Global`*"];
ymax=15;
T=5;
lambda=7;
y[x_,t_]:=ymax Sin[2π((t/T)-(x/lambda))]
Plot3D[y[x,t],{x,-10,10},{t,0,10},PlotStyle->{Magenta,Thickness[0.008]},Boxed->False,AxesOrigin->{0,0,0}]

Nakreslete Vivianiho křivku, která je daná parametricky rovnicemi: x=a (cos^2)t, y=a sin t cos t a z=-a sin t na intervalu a) t∈<0; π>, b) t∈<0; 2π>. Křivku pro a=4 nakreslete červenou barvou tloušťky 0,008.

Řešení

ClearAll["Global`*"];
a=4;
fcex[t_]:=a ((Cos[t])^2)
fcey[t_]:=a Sin[t]Cos[t]
fcez[t_]:=-a Sin[t]
Table[ParametricPlot3D[{fcex[t],fcey[t],fcez[t]},{t,0,i π},PlotStyle->{Red,Thickness[0.008]},AxesOrigin->{0,0,0},Boxed->False,AxesLabel->{"x","y","z"}],{i,1,2,1}]

Zobrazte kulovou plochu o poloměru 8 jednotek se středem v bodě S=[1;0;-1]. Kulová plocha je obecně popsána rovnicí (((x-m))^2)+(((y-n))^2)+(((z-p))^2)-(r^2)=0, přičemž střed má souřadnice S=[m;n;p].

Řešení

r=8;
m=1;
n=0;
p=-1;
kulplocha[x_,y_,z_]:=(((x-m))^2)+(((y-n))^2)+(((z-p))^2)-(r^2)
ContourPlot3D[kulplocha[x,y,z]==0,{x,-10,10},{y,-10,10},{z,-10,10}]

Vykreslete kuželovou plochu s vrcholem v bodě V=[0;0;0].

Řešení

RevolutionPlot3D[{x,x},{x,0,10}]

Jaroslav Reichl, SPŠST Panská, Praha, © 2010