Animace grafu funkce kosinus

Následující aplet umožňuje názorně pochopit základní princip transformace grafu funkce y = a.cos (bx + c) + d. Pomocí posuvníků lze nastavit libovolnou kombinaci koeficientů a, b, c a d. Předdefinované rozsahy koeficientů může uživatel znalý Mathematicy měnit.
Tlačítkem Ulož graf se uloží právě zobrazený graf do aktuální složky (složka, v níž je uložen tento notebook) pod jménem, které je uloženo v proměnné jmenosouboru. K tomuto jménu souboru je při opakovaném ukládání grafu přidáváno pořadové číslo.
Pozor! Při každém spuštění tohoto apletu se začínají soubory číslovat opět od jedné! Tak může dojít k přepsání minule uložených obrázků.

© Jaroslav Reichl, 2008

Příprava pro vykreslení grafu

jmenosouboru="kosinus_.jpg";
cesta=NotebookDirectory[];
pocetulozeni=0;
abarva=Darker[Red];
bbarva=Blue;
cbarva=Orange;
dbarva=Darker[Green];
x1=-2 π;x2=2 π;

AnimaceKosinu[]:=Manipulate[
Column[{
Row[{TraditionalForm[Style["a",20,abarva, FontFamily->Times]],Style[" = ",15],TraditionalForm[Style[a,20,abarva,FontFamily->Times]]}],
Row[{TraditionalForm[Style["b",20,bbarva,FontFamily->Times]],Style[" = ",15],TraditionalForm[Style[b,20,bbarva,FontFamily->Times]]}],
Row[{TraditionalForm[Style["c",20,cbarva,FontFamily->Times]],Style[" = ",15],TraditionalForm[Style[c,20,cbarva,FontFamily->Times]]}],
Row[{TraditionalForm[Style["d",20,dbarva,FontFamily->Times]],Style[" = ",15],TraditionalForm[Style[d,20,dbarva,FontFamily->Times]]}],

grafik=Plot[{Cos[x],a*Cos[b*x+c]+d},{x,x1,x2},PlotStyle->{{RGBColor[0,0,0],Thickness[0.002]},{RGBColor[1,0,0],Thickness[0.008]}},AxesOrigin->{0,0},AxesLabel->{"x","y"},PlotRange->{{x1,x2},{-5,5}},ImageSize->400],

Row[{
Style["y = ",15],
TraditionalForm[Style[
If[a≠1&&a≠0,
a,
""],
15,abarva, FontFamily->Times]],
TraditionalForm[Style[
If[a≠0,
"cos(",
""],15]],
TraditionalForm[Style[
If[b≠1&&b≠0&&a≠0,
b,
""],
15,bbarva, FontFamily->Times]],
Style[
If[a≠0&&b≠0,
If[c≠0,
If[c>0,
"x + ",
"x - "],
"x"],
""],
15],
TraditionalForm[Style[
If[a≠0,
If[b≠0,
If[c≠0,
Abs[c],
""],
c],
""],
15,cbarva,FontFamily->Times]],
Style[
If[a≠0,
If[d≠0,
If[d>0,
") + ",
") - "],
")"],
""],
15],
TraditionalForm[Style[
If[a≠0,
If[d≠0,
Abs[d],
""],
d],
15,dbarva,FontFamily->Times]]
}],
Button[" Ulož graf ",{pocetulozeni=pocetulozeni+1,Export[StringInsert[StringJoin[cesta,jmenosouboru],ToString[pocetulozeni],-5],grafik]},ImageSize->{100,Automatic}]
}],

{{a,1,Style["a",20,abarva]},-2,2,0.1},
{{b,1,Style["b",20,bbarva]},-5,5,0.1},
{{c,0,Style["c",20,cbarva]},-π,π,(π/12)},
{{d,0,Style["d",20,dbarva]},-2,2,0.1},
FrameLabel->{Style["© Jaroslav Reichl, 2008",10,Black,FontFamily->Times],"",Style["Graf funkce: y = a.cos(bx + c) + d",25,Black,FontFamily->Times],""}];

Spuštění animace
Zpracujte běžným způsobem následující buňku a na dotaz, který se objeví, odpovězte ANO.

AnimaceKosinu[]